

===============================================================================
l                       PARANOIA -- Flags and variables                       l
l                                                                             l
l  FLAGS:                                                                     l
l    Flag 1 (* first turn of game if OFF *)                                   l
l    Flag 2 (* computer_request has been made if ON *)                        l
l    Flag 3 (* ultra_violet "lie" if ON *)                                    l
l    Flag 4 (* action_doll has been encountered if ON *)                      l
l    Flag 5 (* has read_letter in ON *)                                       l
l    Flag 6 (* blast_door entered if ON *)                                    l
l    Flag 7 (* need to activate new clone if ON *)                            l
l    Flag 8 (* temporary flag used for "complex" commands *)                  l
l    Flag 9 (* temporary flag used for "complex" commands *)                  l
l                                                                             l
l  VARIABLES:                                                                 l
l    VariableTo 1 (* maxkill = 7 initially *)                                 l
l    VariableTo 2 (* hit_points = 10 initially *)                             l
l    VariableTo 3 (* clone number = 1 initially *)                            l
l    VariableTo 4 (* plato_clone = 3 initially *)                             l
l    VariableTo 5 (* killer_count = 0 initially *)                            l
l    VariableTo 6 (* credits = 160 initially *)                               l
l                                                                             l
===============================================================================


REM: Status Command

COMMAND S
PrintMessage 1 (* Show status of Clone #VAR 3# *)
DoneWithTurn
END_COMMAND

COMMAND INVENTORY
PrintMessage 1 (* Show status of Clone #VAR 3# *)
DoneWithTurn
END_COMMAND


REM: Room 58 Commands -- Starting Room

COMMAND ANY
AtLocation 58
GoToRoom 57
DoneWithTurn
END_COMMAND

REM: Room 2 Commands

COMMAND ANY
AtLocation 2
TurnFlagON 7 (* need a new clone *)
FlagON 2 (* computer request has been made *)
GoToRoom 45
END_COMMAND

COMMAND ANY
AtLocation 2
GoToRoom 32 (* Only if computer request has NOT been made *)
END_COMMAND

REM: Room 3 Commands

COMMAND 1
AtLocation 3
GoToRoom 4 (* 1 - You give your correct clearance *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 3
FlagOFF 3 (* You have not previously claimed ultraviolet status *)
GoToRoom 5 (* 2 - You lie and claim Ultraviolet clearance *)
TurnFlagON 3
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 3
GoToRoom 8 (* 2 - You have already lied at least once before *)
DoneWithTurn
END_COMMAND

REM: Room 4 Commands

COMMAND ANY
AtLocation 4
GoToRoom 9 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 5 Commands

COMMAND 1
AtLocation 5
GoToRoom 6 (* 1 - You open the package and put on the uniform *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 5
GoToRoom 7 (* 2 - You finally come to your senses and run for it *)
DoneWithTurn
END_COMMAND

REM: Room 6 Commands

COMMAND ANY
AtLocation 6
TurnFlagON 3 (* lied about ultra_violet clearance *)
GoToRoom 8 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 7 Commands

COMMAND ANY
AtLocation 7
TurnFlagON 3 (* lied about ultra_violet clearance *)
GoToRoom 8 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 8 Commands

COMMAND ANY
AtLocation 8
GoToRoom 10 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 9 Commands

COMMAND 1
AtLocation 9
TurnFlagON 2 (* computer request has been made *)
GoToRoom 2 (* 1 - You decide to stop here and chat *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 9
GoToRoom 10 (* 2 - You just continue blithely on past *)
DoneWithTurn
END_COMMAND

REM: Room 10 Commands

COMMAND 1
AtLocation 10 (* 1 - You decide to ask The Computer about Christmas *)
FlagOFF 3 (* has NOT lied about ultra_violet clearance *)
GoToRoom 3
DoneWithTurn
END_COMMAND

COMMAND 1
AtLocation 10 (* 1 - You decide to ask The Computer about Christmas *)
PrintMessage 4 (* You change your mind *)
PrintMessage 5 (* and decide to take a tubecar *)
Chance 65 (* 65% chance of this branch *)
PrintMessage 6 (* You catch a purple line car tubecar *)
GoToRoom 13
DoneWithTurn
END_COMMAND

COMMAND 1
AtLocation 10 (* 1 - You decide to ask The Computer about Christmas *)
PrintMessage 7 (* You catch a brown line car tubecar *)
GoToRoom 48
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 10 (* 2 - You decide to take a tubecar *)
PrintMessage 5 (* and decide to take a tubecar *)
Chance 65 (* 65% chance of this branch *)
PrintMessage 6 (* You catch a purple line car tubecar *)
GoToRoom 13
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 10 (* 2 - You decide to take a tubecar *)
PrintMessage 7 (* You catch a brown line car tubecar *)
GoToRoom 48
DoneWithTurn
END_COMMAND

REM: Room 11 Commands

COMMAND 1
AtLocation 11
GoToRoom 3 (* 1 - Ask The Computer for more information about Christmas *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 11
GoToRoom 10 (* 2 - Go directly to Goods Distribution Hall 7-beta *)
DoneWithTurn
END_COMMAND

REM: Room 12 Commands

COMMAND 1
AtLocation 12
GoToRoom 11 (* 1 - Sit down at the table and read the Orange packet *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 12
GoToRoom 57 (* 2 - You stare around the room some more *)
DoneWithTurn
END_COMMAND

REM: Room 13 Commands

COMMAND ANY
AtLocation 13
GoToRoom 14 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 14 Commands

COMMAND ANY
AtLocation 14
GoToRoom 22 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 15 Commands

COMMAND 1
AtLocation 15
GoToRoom 16 (* 1 - You decide to buy the doll. *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 15
GoToRoom 17 (* 2 - You shoot the robot. *)
DoneWithTurn
END_COMMAND

COMMAND 3
AtLocation 15
GoToRoom 22 (* 3 - You ignore the robot and keep searching the hall. *)
DoneWithTurn
END_COMMAND

REM: Room 16 Commands

COMMAND ANY
AtLocation 16
TurnFlagON 4 (* Has now encountered doll *)
SubtractFromVariable 6 50 (* dolls costs 50 credits *)
GoToRoom 22 (* Go to this Room regardless of input *)
DoneWithTurn
END_COMMAND

REM: Room 17 Commands

COMMAND ANY
AtLocation 17 (* first deal with robots damage to you *)
TurnFlagOFF 8 (* Set Temp flag to OFF *)
Chance 25 (* 25 % chance of getting hit *)
TurnFlagON 8 (* Temp flag to indicate he hit you *)
PrintMessage 8 (* You have been hit *)
Chance 40 (* 40 % chance of getting killed *)
TurnFlagON 7 (* Dead - so you need new clone *)
GoToRoom 45 (* Go to new clone Room *)
END_COMMAND

COMMAND ANY
AtLocation 17 (* first deal with robots damage to you *)
FlagOFF 7 (* You are still alive *)
FlagOFF 8 (* You didn't even get hit *)
PrintMessage 9 (* It missed you *)
END_COMMAND

COMMAND ANY
AtLocation 17 (* now deal with your damage to robot *)
FlagOFF 7 (* You are still alive and able to attempt to kill robot *)
TurnFlagOFF 8 (* Set Temp flag to OFF *)
TurnFlagOFF 9 (* Set Temp flag to OFF *)
Chance 40 (* 40 % chance of hitting it *)
TurnFlagON 8 (* Temp flag to indicate you hit it *)
PrintMessage 10 (* You zapped the little bastard! *)
Chance 20 (* 20 % chance of killed it *)
PrintMessage 11 (* You wasted it! *)
TurnFlagON 9 (* Temp flag -- It is dead - so you are done here *)
END_COMMAND

COMMAND ANY
AtLocation 17 (* dealing with your damage to robot *)
FlagOFF 7 (* You are still alive and able to attempt to kill robot *)
FlagOFF 9 (* It is still alive *)
FlagOFF 8 (* It didn't even get hit *)
PrintMessage 14 (* It missed you *)
PrintMessage 10 (* You zapped the little bastard! *)
PrintMessage 11 (* You wasted it! *)
TurnFlagON 9 (* Temp flag -- It is dead - so you are done here *)
END_COMMAND

COMMAND ANY
AtLocation 17 (* dealing with your possible victory *)
FlagOFF 7 (* You are still alive *)
FlagON 9 (* Robot is dead *)
TurnFlagOFF 9 (* Set Temp flag to OFF *)
GoToRoom 22 (* After winning battle -- Go to Room 22 *)
PrintMessage 12 (* You go off to search further *)
Chance 50 (* 50% chance of needing medical attention *)
PrintMessage 13 (* You need to get medibot to patch you up *)
DoneWithTurn (* All done with this round, you kill the little bugger *)
END_COMMAND

REM: Room 18 Commands

COMMAND ANY
AtLocation 18
Chance 75 (* 75 % of going to room 19 *)
GoToRoom 19
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 18
GoToRoom 20 (* 25 % chance of going to room 20 *)
DoneWithTurn
END_COMMAND

REM: Room 19 Commands

COMMAND ANY
AtLocation 19
AddToVariable 5 1 (* Increment count of number killed *)
VariableGT 5 2 (* Penalize player for killing too many *)
GoToRoom 21
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 19
FlagON 5 (* Has read letter *)
GoToRoom 22
DoneWithTurn
END_COMMAND

COMMAND 1
AtLocation 19
GoToRoom 34 (* 1 - You search the body *)
TurnFlagON 5 (* Has now read letter *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 19
GoToRoom 22 (* 2 - You run away like the cowardly dog you are *)
DoneWithTurn
END_COMMAND

REM: Room 20 Commands

COMMAND ANY
AtLocation 20
GoToRoom 22 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 21 Commands

COMMAND ANY
AtLocation 21
TurnFlagON 7 (* need a new clone *)
GoToRoom 45
END_COMMAND

REM: Room 22 Commands

COMMAND ANY
AtLocation 22
Chance 25 (* 25 % chance of going to room 18 *)
GoToRoom 18
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 22
Chance 33 (* 25 % chance of going to room 15 *)
GoToRoom 15
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 22
Chance 50 (* 25 % chance of going to room 18 *)
GoToRoom 18
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 22
GoToRoom 29 (* 25 % chance *)
DoneWithTurn
END_COMMAND

REM: Room 23 Commands

COMMAND 1
AtLocation 23
GoToRoom 28 (* 1 - You tell them that it was really only a bad joke *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 23
GoToRoom 24 (* 2 - You want to fight it out, one against twelve *)
DoneWithTurn
END_COMMAND

REM: Room 24 Commands

COMMAND 1
AtLocation 24
GoToRoom 28 (* 1 - You change your mind and tell them it was only a bad joke *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 24
GoToRoom 25 (* 2 - You REALLY want to fight it out *)
DoneWithTurn
END_COMMAND

REM: Room 25 Commands

COMMAND 1
AtLocation 25
GoToRoom 28 (* 1 - You tell them that it was really only a bad joke *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 25
GoToRoom 26 (* 2 - You are going to shot *)
DoneWithTurn
END_COMMAND

REM: Room 26 Commands

COMMAND ANY
AtLocation 26
TurnFlagON 7 (* need a new clone *)
GoToRoom 32
END_COMMAND

REM: Room 27 No Commands for this room -- Game Ends here

REM: Room 28 Commands

COMMAND ANY
AtLocation 28
GoToRoom 26 (* Regardless *)
END_COMMAND

REM: Room 29 Commands

COMMAND 1
AtLocation 29
SubtractFromVariable 6 30 (* You pay 30 credits for info *)
GoToRoom 30 (* 1 - You pay the 30 credits for the info *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 29
GoToRoom 31 (* 2 - You would rather threaten him for the information *)
DoneWithTurn
END_COMMAND

COMMAND 3
AtLocation 29
GoToRoom 22 (* 3 - You ignore him and walk away *)
DoneWithTurn
END_COMMAND

REM: Room 30 Commands

COMMAND 1
AtLocation 30
GoToRoom 56 (* 1 - You use your mutant power on opening the door *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 30
GoToRoom 33 (*  2 - You just go through the door anyway *)
DoneWithTurn
END_COMMAND

COMMAND 3
AtLocation 30
GoToRoom 22 (* 3 - You decide it's too dangerous and walk away *)
DoneWithTurn
END_COMMAND

REM: Room 31 Commands

COMMAND 1
AtLocation 31
SubtractFromVariable 6 30 (* You pay 30 credits for info *)
GoToRoom 30 (* 1 - You pay the 30 credits for the info *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 31
GoToRoom 22 (* 2 - You pssfft go away stupid *)
DoneWithTurn
END_COMMAND

REM: Room 32 Commands

COMMAND ANY
AtLocation 32
FlagOFF 7 (* new clone -- already activated *)
GoToRoom 22 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 33 Commands

COMMAND ANY
AtLocation 33
TurnFlagON 6 (* by blast door *)
FlagON 3 (* Lied about Ultra-violet status *)
GoToRoom 35 (* If Ultra-Violet status *)
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 33
GoToRoom 36 (* If NOT Ultra-Violet *)
DoneWithTurn
END_COMMAND

REM: Room 34 Commands

COMMAND 1
AtLocation 34
TurnFlagON 5 (* has read letter *)
GoToRoom 46 (* 1 - You go to the computer terminal to expose the commies *)
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 34
GoToRoom 22 (* 2 - You wander off *)
DoneWithTurn
END_COMMAND

REM: Room 35 Commands

COMMAND ANY
AtLocation 35
TurnFlagON 7 (* need a new clone *)
GoToRoom 32
END_COMMAND

REM: Room 36 Commands

COMMAND 1
AtLocation 36  (* 1 - You voice an objection *)
TurnFlagON 7 (* need a new clone *)
GoToRoom 32
END_COMMAND

COMMAND 2
AtLocation 36
GoToRoom 23 (* 2 - You register as a mutant *)
DoneWithTurn
END_COMMAND

COMMAND 3
AtLocation 36
GoToRoom 37 (* 3 - You go to the seminar *)
DoneWithTurn
END_COMMAND

REM: Room 37 Commands

COMMAND ANY
AtLocation 37
GoToRoom 38 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 38 Commands

COMMAND 1
AtLocation 38  (* 1 - You volunteer *)
GoToRoom 39
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 38
GoToRoom 40 (* 2 - You try to hide *)
DoneWithTurn
END_COMMAND

REM: Room 39 Commands

COMMAND ANY
AtLocation 39
GoToRoom 41 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 40 Commands

COMMAND ANY
AtLocation 40 (* first deal with his damage to you *)
Chance 30 (* 25 % chance of getting hit *)
PrintMessage 15 (* You have been hit and are numb all over *)
GoToRoom 49 (* Go to new Room *)
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 40 (* dealing with his damage to you *)
PrintMessage 16 (* He missed you *)
END_COMMAND

COMMAND ANY
AtLocation 40 (* now deal with your damage to him *)
Chance 40 (* 40 % chance of your hitting him *)
PrintMessage 17 (* You blow his head off! *)
GoToRoom 50 (* Go to new Room *)
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 40 (* dealing with your damage to robot *)
PrintMessage 18 (* You missed him *)
PrintMessage 20 (* A - Continue the game *)
DoneWithTurn (* All done with this round, you are both still alive *)
END_COMMAND

REM: Room 41 Commands

COMMAND 1
AtLocation 41  (* 1 - You give the code *)
GoToRoom 42
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 41
GoToRoom 43 (* 2 - You ignore the secret contact *)
DoneWithTurn
END_COMMAND

REM: Room 42 Commands

COMMAND 1
AtLocation 42  (* 1 - You run for it *)
GoToRoom 51
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 42
GoToRoom 52 (* 2 - You wait for the guard *)
DoneWithTurn
END_COMMAND

REM: Room 43 Commands

COMMAND 1
AtLocation 43  (* 1 - You look for a computer terminal *)
GoToRoom 44
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 43
GoToRoom 55 (* 2 - You go to the ceremony *)
DoneWithTurn
END_COMMAND

REM: Room 44 Commands

COMMAND 1
AtLocation 44  (* 1 - You register as a mutant *)
GoToRoom 23
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 44
GoToRoom 46 (* 2 - You chat about the commies *)
DoneWithTurn
END_COMMAND

COMMAND 3
AtLocation 44  (* 3 - You go to the ceremony after all *)
GoToRoom 55
DoneWithTurn
END_COMMAND

REM: Room 45 Commands

COMMAND ANY
AtLocation 45
FlagOFF 7 (* new clone -- already activated *)
GoToRoom 10 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 46 Commands

COMMAND 1
AtLocation 46  (* 1 - You insist in talking about the commies *)
GoToRoom 53
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 46
GoToRoom 54 (* 2 - You change the subject *)
DoneWithTurn
END_COMMAND

REM: No Room 47 Commands -- Game ends here

REM: Room 48 Commands

COMMAND ANY
AtLocation 48
TurnFlagON 7 (* need a new clone *)
GoToRoom 45
END_COMMAND

REM: Room 49 Commands

COMMAND ANY
AtLocation 49
TurnFlagON 7 (* need a new clone *)
GoToRoom 32
END_COMMAND

REM: Room 50 Commands

COMMAND ANY
AtLocation 50
GoToRoom 41 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 51 Commands

COMMAND ANY
AtLocation 51
TurnFlagON 7 (* need a new clone *)
GoToRoom 32
END_COMMAND

REM: Room 52 Commands

COMMAND ANY
AtLocation 52
GoToRoom 2 (* Regardless *)
DoneWithTurn
END_COMMAND

REM: Room 53 Commands

COMMAND 1
AtLocation 53  (* 1 - You tell about the commies *)
GoToRoom 47
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 53
GoToRoom 54 (* 2 - You talk about something less dangerous *)
DoneWithTurn
END_COMMAND

REM: Room 54 Commands

COMMAND ANY
AtLocation 54
TurnFlagON 7 (* need a new clone *)
FlagOFF 6 (* Has gone through blast door *)
GoToRoom 45
END_COMMAND

COMMAND ANY
AtLocation 54
GoToRoom 32 (* Has NOT gone through blast door *)
END_COMMAND

REM: No Room 55 Commands -- Game ends here

REM: Room 56 Commands

COMMAND 1
AtLocation 56  (* 1 - You open the door and step through *)
GoToRoom 33
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 56
GoToRoom 22 (* 2 - You go looking for more information *)
DoneWithTurn
END_COMMAND

REM: Room 57 Commands

COMMAND 1
AtLocation 57  (* 1 - You sit down to read the folder *)
GoToRoom 11
DoneWithTurn
END_COMMAND

COMMAND 2
AtLocation 57
GoToRoom 12 (* 2 - You leave the room *)
DoneWithTurn
END_COMMAND


REM: General ANY commands

COMMAND ANY
FlagOFF 1 (* First turn of game - initilize values *)
SetVariableTo 3 1 (* clone number *)
SetVariableTo 5 0 (* killer_count *)
SetVariableTo 6 160 (* credits *)
TurnFlagON 1 (* no longer first turn of game *)
END_COMMAND

REM: ANY commands necessary to create new clone
REM: Will only be acted upon if Flag 7 has been turned ON in a prior command

COMMAND ANY
FlagON 7 (* Need to activate new clone *)
PrintMessage 2 (* Clone #VAR 3# has just died. *)
AddToVariable 3 1 (* increment clone number *)
MinusScore 10 (* Subtract 10 points for dying *)
VariableGT 3 6 (* Exceeds max of 6 clones *)
GoToRoom 27 (* Loser's Hall of Shame *)
TurnFlagOFF 7 (* no longer need to activate a clone *)
LookAtRoom (* Describe room *)
DoneWithTurn
END_COMMAND

COMMAND ANY
FlagON 7 (* Need to activate new clone *)
SetVariableTo 5 0 (* killer_count *)
SetVariableTo 2 10 (* hit_points *)
PrintMessage 3 (* Clone #VAR 3# has just been activated. *)
TurnFlagOFF 7 (* no longer need to activate a clone *)
LookAtRoom (* Describe room *)
DoneWithTurn
END_COMMAND


